home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #1 / Ham Radio 2000.iso / ham2000 / tcp_ip / ka9q / nos_kit / finish.bat < prev    next >
Encoding:
DOS Batch File  |  1991-03-01  |  3.3 KB  |  108 lines
  1. echo off
  2. rem  ==========================================================================
  3. rem
  4. rem        F I N I S H . B A T
  5. rem
  6. rem    Copyright 1991 Dave Fritsche (wb8zxu)
  7. rem    All rights reserved.
  8. rem    Non-profit redistribution is allowed
  9. rem
  10. rem    This batch file is run after the install program has created all the
  11. rem    needed subdirectories, and unique configuration files.  The command
  12. rem    line parameters passed to this batch file are:
  13. rem        %1 - The drive that contains the distribution files (e.g. a:)
  14. rem        %2 - Directory path to the install files on the dist. drive
  15. rem        %3 - The target drive for the installation (e.g. c:)
  16. rem        %4 - The target drive's base directory for installing NOS
  17. rem        %5 - Same as %2, except no trailing "\"
  18. rem        %6 - "ka9q" if ka9q-nos is to be installed
  19. rem        %7 - "g1emm" if g1emm-nos is to be installed
  20. rem        %8 - "bm" if the BM mailer is to be installed
  21. rem        %9 - "netnews" if the NETNEWS software is to be installed
  22. rem  ==========================================================================
  23. rem
  24. rem    ----------------------------
  25. rem    Change to the "target" drive
  26. rem    ----------------------------
  27. %3
  28. if %6X==ka9qX goto INSNOS
  29. if not %7X==g1emmX goto NONOS
  30. :INSNOS
  31. rem    ------------------------------
  32. rem    Install the mailbox help files
  33. rem    ------------------------------
  34. cd %4
  35. cd spool\help
  36. %1%2unzip %1%2nos_misc help/*.*
  37. rem    -------------------------
  38. rem    Install the documentation
  39. rem    -------------------------
  40. cd %4
  41. cd pub\doc
  42. %1%2unzip %1%2nos_misc doc/*.*
  43. rem    -------------------------------
  44. rem    Install the KISS TNC ROM images
  45. rem    -------------------------------
  46. cd %4
  47. cd pub\kiss
  48. %1%2unzip %1%2nos_misc kiss/*.*
  49. rem    ------------------------------------------------------------------------
  50. rem    Install the uudecoder sources for mailbox users (usefull for DU command)
  51. rem    ------------------------------------------------------------------------
  52. cd %4
  53. cd pub\uudecode
  54. %1%2unzip %1%2nos_misc uudecode/*.*
  55. rem    ----------------------------------------
  56. rem    Install the KA9Q executable if requested
  57. rem    ----------------------------------------
  58. if not %6X==ka9qX goto NOKA9Q
  59. cd %4
  60. cd bin
  61. %1%2unzip %1%2nos_exe nos1130d.exe
  62. ren nos1130d.exe noska9q.exe
  63. cd %4
  64. cd pub\doc
  65. %1%2unzip %1%2nos_exe nos1130d.doc
  66. ren nos1130d.doc noska9q.txt
  67. :NOKA9Q
  68. rem    -----------------------------------------
  69. rem    Install the G1EMM executable if requested
  70. rem    -----------------------------------------
  71. if not %7X==g1emmX goto NOG1EMM
  72. cd %4
  73. cd bin
  74. %1%2unzip %1%2nos_exe b_113016.exe
  75. ren b_113016.exe nosg1emm.exe
  76. cd %4
  77. cd pub\doc
  78. %1%2unzip %1%2nos_exe b_113016.doc
  79. ren b_113016.doc nosg1emm.txt
  80. :NOG1EMM
  81. rem
  82. :NONOS
  83. rem    ------------------------------------
  84. rem    Install BM mail program if requested
  85. rem    ------------------------------------
  86. if not %8X==bmX goto NOBM
  87. cd %4
  88. cd bin
  89. %1%2unzip %1%2nos_exe bm.exe
  90. :NOBM
  91. rem    -------------------------
  92. rem    Install the misc utilites
  93. rem    -------------------------
  94. if %6X==ka9qX goto INSMISC
  95. if %7X==g1emmX goto INSMISC
  96. if not %9X==netnewsX goto NOMISC
  97. :INSMISC
  98. cd %4
  99. cd bin
  100. %1%2unzip %1%2nos_misc misc_bin/*.*
  101. :NOMISC
  102. rem    -------------------------------------------------------
  103. rem    All done.  Change back to the distribution disk and dir
  104. rem    -------------------------------------------------------
  105. :END
  106. %1
  107. cd %5
  108.